home *** CD-ROM | disk | FTP | other *** search
/ Ham Radio / Ham Radio CD-ROM (Emerald Software) (1995).ISO / ant / vhf-yagi / vhf-yagi.bas
BASIC Source File  |  1985-08-25  |  2KB  |  56 lines
  1. 100 'This program calculates the demensions of a VHF Yagi antenna.
  2. 110 '
  3. 120 'Design assumptions are:
  4. 130 '  1. Driven element length in inches is 5600/frequency in MHZ.
  5. 140 '  2. The reflector is 5% longer than the driven element.
  6. 150 '  3. Reflector and first director spacing is 0.2 wavelengths from driven.
  7. 160 '  4. The first director is 5% shorter than the driven element.
  8. 170 '     Subsequent director lengths are calculated by adding 1% to
  9. 180 '     the shortening factor of the previous director. For example,
  10. 190 '     the 2nd director is 6% shorter than the driven element,
  11. 200 '     the 3rd is 7% shorter, the 4th, 8% shorter, etc.
  12. 210 '  5. Director spacing is 110% of previous spacing. Spacing starts
  13. 220 '     at 0.2 wavelengths.
  14. 230 '
  15. 240 ' The program is well documented via remarks, so any of the above
  16. 250 ' assumptions may be easily changed.
  17. 260 '
  18. 270 '-------------------- PROGRAM BEGINS --------------------------------------
  19. 280 '
  20. 290 CLS
  21. 300 DEFINT I
  22. 310 INPUT"WHAT FREQUENCY (MHZ) ";FREQ
  23. 320 INPUT"HOW MANY ELEMENTS (3 MINIMUM) ";ELNO
  24. 330 WL = 11808/FREQ 'wavelength in free space (inches)
  25. 340 DR = 5600/FREQ 'driven element length (inches)
  26. 350 RF = DR * 1.05 'reflector length
  27. 360 SPR = WL * .2 'reflector spacing
  28. 370 PL(1) = DR * .95'first director length
  29. 380 SPP(1) = WL * .2 'first director spacing
  30. 390 FOR I = 2 TO (ELNO -2)
  31. 400 SPP(I) = SPP(I-1) * 1.1 'each director spacing 10% greater than previous
  32. 410 PL(I) = DR * (100 - (4 + I))*.01 'director length
  33. 420 LN1 = LN1 + SPP(I) 'keep track of overall length
  34. 430 NEXT
  35. 440 DEF FNX(X) = INT(X*100+.5)*.01 'function to round off printing to 2 dec.
  36. 450 LNT = SPR + SPP(1) + LN1 'total beam length
  37. 460 LPRINT"DESIGN DATA FOR VHF YAGI BEAM ANTENNA: "
  38. 470 LPRINT
  39. 480 LPRINT"---- DESIGN FREQUENCY IS";FREQ;" MHZ"
  40. 490 LPRINT"---- TOTAL NUMBER OF ELEMENTS IS";ELNO
  41. 500 LPRINT
  42. 510 LPRINT
  43. 520 LPRINT TAB(35);"LENGTH IN INCHES"
  44. 530 LPRINT "REFLECTOR";TAB(40);FNX(RF)
  45. 540 LPRINT "REFLECTOR TO DRIVEN";TAB(41);FNX(SPR)
  46. 550 LPRINT "DRIVEN";TAB(40);FNX(DR)
  47. 560 LPRINT "DRIVEN TO 1st DIRECTOR";TAB(41);FNX(SPP(1))
  48. 570 LPRINT "1st DIRECTOR LENGTH";TAB(40);FNX(PL(1))
  49. 580 LPRINT
  50. 590 FOR I = 2 TO (ELNO -2)
  51. 600 LPRINT"DIRECTOR No.";I;" LENGTH IS";FNX(PL(I));" INCHES"
  52. 610 LPRINT "SPACED";FNX(SPP(I));" INCHES FROM DIRECTOR No.";I-1
  53. 620 LPRINT
  54. 630 NEXT
  55. 640 LPRINT "------ OVERALL BEAM LENGTH IS";FNX(LNT);" INCHES ------"
  56.